フォルダ、ファイルの選択ダイアログ

• [参照] ダイアログ ボックス(ファイル参照)

  '[参照] ダイアログ ボックスの FileDialog オブジェクトを作成します。
    Dim fd As FileDialog
    
    Set fd = Application.FileDialog(msoFileDialogFilePicker)
   '選択した各アイテムのパスを保存す変数を宣言します。
    Dim vrtSelectedItem As Variant
    
    'プロパティの設定
    With fd
        .Title = "サンプルダイアログ（ファイル参照）"
        'フィルターの設定
        .Filters.Clear
        .Filters.Add "テキスト", "*.txt; *.csv"
        .Filters.Add "エクセル", "*.xls"
        .Filters.Add "Access", "*.mdb"
        .Filters.Add "イメージ", "*.gif; *.jpg; *.jpeg"
        .Filters.Add "すべてのファイル", "*.*"
        .FilterIndex = 5
        
        .InitialView = msoFileDialogViewDetails
        .InitialFileName = CurrentProject.Path
        .AllowMultiSelect = True

        '[参照] ダイアログ ボックスを表示します。
        If .Show = -1 Then
            'ユーザーがアクション ボタンをクリックした場合
            For Each vrtSelectedItem In .SelectedItems
                Debug.Print "選択したアイテムのパス : " & vrtSelectedItem
            Next vrtSelectedItem
        Else
           'ユーザーが [キャンセル] をクリックした場合
        End If
    End With

    'オブジェクトの変数に Nothing を設定します。
    Set fd = Nothing

• [参照] ダイアログ ボックス(フォルダ参照)

 '[参照] ダイアログ ボックスの FileDialog オブジェクトを作成します。
    Dim fd As FileDialog
    
    Set fd = Application.FileDialog(msoFileDialogFolderPicker)
   '選択した各アイテムのパスを保存す変数を宣言します。
    Dim vrtSelectedItem As Variant
    
    'プロパティの設定
    With fd
        .Title = "サンプルダイアログ（フォルダ参照）"
        
        .InitialView = msoFileDialogViewDetails
        .InitialFileName = "D:\"

        '[参照] ダイアログ ボックスを表示します。
        If .Show = -1 Then
            'ユーザーがアクション ボタンをクリックした場合
            For Each vrtSelectedItem In .SelectedItems
                FDFolderPicker = vrtSelectedItem
            Next vrtSelectedItem
        Else
           'ユーザーが [キャンセル] をクリックした場合
        End If
    End With

    'オブジェクトの変数に Nothing を設定します。
    Set fd = Nothing

Access_Tips_Dialog ボックスを表示する方法 - Access_VBA講座